Exl50

• 25.08.23
• 16:39
• Artikel
• +1

Hallo, im Folgenden die Formatierung der obigen LAMBDA-Formel. Sie funktioniert bestens mit dem Microsoft-Add-In "Excel Labs" im deutschen Excel. Auch die Umschaltung in die englische Formel-Variante ist nur 1 Schalter weit entfernt.
Test = Lambda(diesesFach;SuchFächer;TabelleLehrer; [Idx];
WENNFEHLER(
WENN(
diesesFach="";
"";
LET(
RNGdiesesFach; diesesFach;
RNGSuchFächer; SuchFächer;
RNGalleLehrer; WEGLASSEN(INDEX(TabelleLehrer;;1);1);
RNGalleFächer; WEGLASSEN(INDEX(TabelleLehrer;1;);;1);
RNJaNeinMatrix; WEGLASSEN(TabelleLehrer;1;1);
NrIdx; WENN(WURDEAUSGELASSEN(Idx);4;Idx);

JaNeinSuchFächerAndere; FILTER(
RNJaNeinMatrix;
NACHSPALTE(
RNGalleFächer;
LAMBDA(Fach;
( ZÄHLENWENN(RNGSuchFächer; Fach) - (Fach=RNGdiesesFach) )=1
)
)
);
LehrerAndereFächer;FILTER(
RNGalleLehrer;
NACHZEILE(
--ISTZAHL(
FINDEN(
"ja";
JaNeinSuchFächerAndere
)
);
LAMBDA(Ja;max(Ja))
)=1
);
LehrerRNGdiesesFach; FILTER(
RNGalleLehrer;
INDEX(
RNJaNeinMatrix;
;
VERGLEICH(
RNGdiesesFach;
WEGLASSEN(
INDEX(TabelleLehrer;1;);
;
1
);
0
)
)="ja"
);
Ergebnis;FILTER(
LehrerRNGdiesesFach;
ISTZAHL(
VERGLEICH(
LehrerRNGdiesesFach;
LehrerAndereFächer;
0
)
)
);
WAHL(NrIdx;JaNeinSuchFächerAndere;LehrerAndereFächer;LehrerRNGdiesesFach;Ergebnis)
)
);""
)
);;

• 25.08.23
• 16:31
• Artikel
• +1

@bAssI: